Хотя предыдущее объяснение вычисления факториала 2! исчерпывающе понятно, оно имеет недостаток. Это чрезмерная полнота объяснения, что приводит, даже для очень маленькой базы знаний, к выводу слишком большого объема информации. Экранный текст, произведенный экспертной системой, имеющей сотни правил, становится невразумительным.
Поэтому дополняем программу 8 возможностью указать, что достаточно объяснять при получении решения. Для этого делаем небольшую модификацию программы и используем предикат explainThis(f(_,_)), который указывает вывод каких именно предикатов нужно объяснять.
% программа 9
:- dynamic explainThis/1.
how(Goal):-
solve(Goal,Proof),
interpret(Proof).
solve(true,true):-!.
solve((A,B),(ProofA,ProofB)):-!,
solve(A,ProofA),
solve(B,ProofB).
solve(not(A),'не доказуемо'(A)):-!,
not(solve(A,_)).
solve(A,(A:-Proof)):-
not system(A),
clause(A,B),
solve(B,Proof).
solve(A,(A:-true)):-
system(A),
A.
system(is(_,_)).
system(_=_).
system(_<_).
system(_>_).
system(write(_)).
system(nl).
interpret((ProofA,ProofB)):-!,
interpret(ProofA),
interpret(ProofB).
interpret((A:-'как было сказано')):-!,
nl,write(A),write(' <= как было сказано'),nl.
interpret('не доказуемо'(A)):-!,
nl,write(A),write(' <= не доказуемо'),nl.
interpret(Proof):-
fact(Proof,Fact),
explainFact(Fact).
interpret(Proof):-
rule(Proof,Head,Body,Proof1),
explainRule(Head,Body),
interpret(Proof1).
fact((Fact:-true),Fact).
rule((Goal:-Proof),Goal,Body,Proof):-
not(Proof=true),
extract_body(Proof,Body).
extract_body((ProofA,ProofB),(BodyA,BodyB)):-
!,
extract_body(ProofA,BodyA),
extract_body(ProofB,BodyB).
extract_body((Goal:-Proof),Goal).
extract_body('не доказуемо'(B),not(B)).
display_rule(rule(A,B)):-
nl,write('Если '),
write_conjunction(B),
write(' то '),
write(A),nl.
write_conjunction((A,B)):-
!,write(A),write(' и '),
write_conjunction(B).
write_conjunction(A):-
write(A),nl.
explainRule(Head,Body):-
explainThis(Head),!, % об'яснять ли вывод предиката
nl,write(Head),
write(' доказано с использованием правила '),
display_rule(rule(Head,Body)).
explainRule(_,_).
explainFact(Fact):- % об'яснять ли вывод факта
explainThis(Fact),!,
nl,write(Fact),write(' - это факт'),nl.
explainFact(_).
Теперь укажем в программе, что объяснять нужно только вывод предиката факториал f/2.
explainThis(f(_,_)).
Получаем объяснение того, что 4! = 24
?- how(f(4,X)).
f(4, 24) доказано с использованием правила
Если 4 > 0 и 3 is 4 - 1 и f(3, 6) и 24 is 4 * 6
то f(4, 24)
f(3, 6) доказано с использованием правила
Если 3 > 0 и 2 is 3 - 1 и f(2, 2) и 6 is 3 * 2
то f(3, 6)
f(2, 2) доказано с использованием правила
Если 2 > 0 и 1 is 2 - 1 и f(1, 1) и 2 is 2 * 1
то f(2, 2)
f(1, 1) доказано с использованием правила
Если 1 > 0 и 0 is 1 - 1 и f(0, 1) и 1 is 1 * 1
то f(1, 1)
f(0, 1) - это факт
X = 24
Yes
|
Главная
Каталог файлов
