Внешнее БД Турбо Пролога имеют вид текстовых файлов, содер-
жащих перечень фактов. Большинство современных БД хранятся в
одном из стандартных форматов баз данных. Турбо Пролог обеспе-
чивает взаимодействие с любыми файлами MS DOS на нижнем уровне.
Рассмотрим механизм взаимодействия ТП с БД, хранящейся в DBF-
формате.
Ниже приводится текст основной программы EX2, обеспечивающей
чтение информации из файлов системы dBASE (основные поля базы
данных хранятся в DBF-файле, поля примечаний в DBT-файле).
#M
project "xdbase3"
DOMAINS
File = fp ; mfp
GLOBAL PREDICATES
real_ints(REAL,INTEGER,INTEGER,INTEGER,INTEGER)-(o,i,i,i,i) language c
include "readext.pro"
include "dbase3.rul"
PREDICATES
list_recl(FldNameL,Dbase3RecL)
list_rec(FldNameL,Dbase3Rec)
list_elem(Dbase3Elem)
NoofNL(Integer)
PressAKey
doPrompt
CLAUSES
list_recL(_,[]) :- !.
list_recL(FldNameL,[Rec|RecL]) :-
nl,nl,
list_rec(FldNameL,Rec), PressAkey,
list_recL(FldNameL,RecL).
list_rec([],[]) :- !.
list_rec([FldName|FldNames],[Elem|Elems]) :-
writef("\n%-12: ",FldName),
list_elem(Elem),
list_rec(FldNames,Elems).
list_elem(char(Str)) :- write(Str).
list_elem(real(Real)) :- write(Real).
list_elem(logical(CH)):- write(CH).
list_elem(memo(Str)) :- write(Str).
list_elem(date(Date)) :- write(Date).
NoofNL(N) :- N<=0,!.
NoofNL(N) :- nl, N2=N-1, NoofNL(N2).
PressAKey :-
makewindow(_,_,_,_,MinR,_,NoofR,_),
cursor(R,_), R<=MinR+NoofR-8,!.
PressAKey :- doPrompt,cursor(R,C), scroll(R,0),cursor(0,C).
doPrompt:-
makewindow(Nr,Att,_,_,MinR,MinC,NoofR,NoofC),
MinR2=MinR+NoofR-1, MinC2=MinC+NoofC/3+1,
str_len(" Нажмите любую клавишу",Len), Len2=Len+1, bitxor(Att,8,Att2),
makewindow(Nr,Att2,0,"",MinR2,MinC2,1,Len2),
write(" Нажмите любую клавишу"),
readdevice(FP), readdevice(keyboard), readchar(_), readdevice(FP),
removewindow.
GOAL
openread(fp,"client.dbf"), filemode(fp,0), readdevice(fp),
openread(mfp,"client.dbt"),filemode(mfp,0),
init_dbase3(TotRecs,FldNameL,FldDescL),
filepos(fp,Fposfp,0), filepos(mfp,Fposmfp,0),
rd_Dbase3File(TotRecs,mfp,FldDescL,RecL),
makewindow(85,$1E,$1A," dBASE III ",0,0,25,40),
list_recL(FldNameL,RecL), DoPrompt,
window_attr(27). #P
Используемые в программе файлы client.dbf и client.dbt
открываются в текстовом режиме (filemode(_,0)). Предикат
init_dbase3 обеспечивает чтение заголовка БД и передачу коли-
чества записей, имен полей и их типов в основную программу.
После выполнения предиката init_dbase3 позиции начала записей
в БД (конец заголовка) заполняются в Fposfp и Fposmfp. Преди-
кат rd_Dbase3File осуществляет чтение файла БД и загрузку
информации в структуру списков Пролога. Предикат list_recl
выполняет вывод на экран терминала записей DBF-файла.
Предикаты обработки DBF файла занесены в отдельный файл
dbase3.rul, текст которого с коментариями приводится ниже.
#M
Domains
/*************************************************************
Описание базы данных на Прологе
*************************************************************/
Dbase3RecL = Dbase3Rec* /* БД = список записей */
Dbase3Rec = Dbase3Elem* /* Каждая запись = список полей */
Dbase3Elem = char(String); /* Каждый элемент поля может быть */
real(Real); /* либо срокой, либо числом, */
logical(Bool);/* либо логической величиной, */
memo(String); /* либо ссылкой на примечание
(10 цифр - номер блока DBT-файла) */
date(String) /* либо датой в формате YYYY MM DD */
Bool = Char /* Y y N n T t F f или Пробел */
FldDescL = FldDesc* /* Список описателей полей */
FldDesc = flddesc(Dbase3Type,Integer) /* Структура описателя */
Dbase3Type = ch;r;l;m;d /* Типы полей БД */
FldNameL = String* /* Список названий полей */
PREDICATES
/* Предикаты чтения БД */
Init_Dbase3(Real,FldNameL,FldDescL)
rd_dbase3_DbaseHeader(Real)
rd_dbase3_fieldDescL(FldNameL,FldDescL)
rd_dbase3File(Real,File,FldDescL,Dbase3RecL)
rd_dbase3_DataRec(File,FldDescL,dBase3Rec)
rd_dbase3_elem(File,FldDesc,dBase3Elem)
conv_FldType(Char,dBASE3Type)
rd_dbase3_DataRec1(Real,Real,File,FldDescL,dBase3Rec)
CLAUSES
Init_Dbase3(TotRecs,FldNameL,FldDescL):-
rd_dbase3_DbaseHeader(TotRecs),
rd_dbase3_fieldDescL(FldNameL,FldDescL).
/* Чтение заголовка БД dBASE III */
rd_dbase3_DbaseHeader(TotRecs):-
ignore(4), /* ID, дата последнего обновления, размер записи */
read_long(TotRecs), /* Количество записей в БД */
ignore(24). /* Размеры заголовка и записи */
/* Чтение Описателей Полей */
rd_dbase3_fieldDescL([FldName|FldNameL],[fldDesc(Type,Len)|FldDescL]):-
readchar(Ch), Ch<>'\013',!, /* CR means final array field */
read_strArr(10,Name), frontchar(FldName,Ch,Name),
readchar(T), conv_FldType(T,Type),
ignore(4),
readchar(L), char_int(L,Len),
ignore(15),
rd_dbase3_FieldDescL(FldNameL,FldDescL).
rd_dbase3_FieldDescL([],[]):-readchar(_).
conv_FldType('C',ch):-!.
conv_FldType('N',r):-!.
conv_FldType('L',l):-!.
conv_FldType('M',m):-!.
conv_FldType('D',d):-!.
/* Чтение Записей */
rd_dbase3File(0,_,_,[]):-!.
rd_dbase3File(N,MFP,FldDescL,[Rec|RecL]):-
rd_dbase3_DataRec1(N,N2,MFP,FldDescL,Rec),
rd_dbase3File(N2,MFP,FldDescL,RecL).
rd_dbase3_datarec1(Ni,No,MFP,FldDescL,Rec):-
readchar(NotDel), NotDel=' ',!, No=Ni-
1,rd_dbase3_DataRec(MFP,FldDescL,Rec).
rd_dbase3_datarec1(Ni,No,MFP,FldDescL,Rec):-
Ni2=Ni-1, rd_dbase3_datarec(MFP,FldDescL,_),
rd_dbase3_DataRec1(Ni2,No,MFP,FldDescL,Rec).
rd_dbase3_DataRec(_,[],[]):-!.
rd_dbase3_DataRec(MFP,[FldDesc|FldDescL],[Elem|ElemL]):-
rd_dbase3_elem(MFP,FldDesc,Elem), rd_dbase3_DataRec(MFP,FldDescL,ElemL).
rd_dbase3_elem(_,fldDesc(ch,Len),char(Str)):-!,read_strArr(Len,Str).
rd_dbase3_elem(_,fldDesc(l,Len),logical(Char)):-!,
readchar(Char), ToSkip=Len-1, ignore(ToSkip).
rd_dbase3_elem(_,fldDesc(r,Len),real(Real)):-!,
read_strArr(Len,Str), str_real(Str,Real).
rd_dbase3_elem(MFP,fldDesc(m,Len),memo(Memo)):-!,
read_strArr(Len,BlkNo),
str_int(BlkNo,P), Pos=P*512,
readdevice(FP), readdevice(MFP),
filepos(MFP,Pos,0), read_strCtrlZ(Memo),
readdevice(FP).
rd_dbase3_elem(_,fldDesc(d,Len),date(Date)):-!,read_strArr(Len,Date).#P
|
Главная
Каталог файлов
